[Linux-ha-dev] Re: [Linux-ha-cvs] Linux-HA CVS: linux-ha by gshi
from
Horms
horms at verge.net.au
Tue Jun 22 03:04:17 MDT 2004
On Mon, Jun 21, 2004 at 10:53:19AM +0200, Andrew wrote:
>
> On Jun 21, 2004, at 3:43 AM, Horms wrote:
> >>>
> >>>I am not sure that I agree with the approach.
> >>>Yes, the module should not be built if the library is not there.
> >>>But it should still get included in a make dist. I don't
> >>>believe this allows for that.
> >>
> >>I'm not sure what's wrong. Can you fix it?
> >
> >Sure. What I would propose is always including the Makefile.am and
> >its directory in the build. And having the Makefile.am to only
> >build the code if it is needed. There might be other optional
> >pieces of code in the tree that are in the same boat.
>
> The CRM could probably do with that treatment.
>
> >
> >Would you like me to look into this and produce a patch / CVS commit ?
I have gone over the whole tree and made it so
all, and I mean all source files should now be included in the
distrubted tar ball. Curiously I discovered some code,
the snmp_subagent (snmp_subagent/), and perl bindings (lib/bindings/)
that would never be incuded in the tar ball, no matter what.
Also, lmb, I had to do some surgery to lib/bindings/Makefile.am
to inculde a bunch of extra files in the tar ball and make it
build under makedistcheck. You might want to doble check what
I have done there.
Patch is attached for refereance.
--
Horms
-------------- next part --------------
Index: Makefile.am
===================================================================
RCS file: /home/cvs/linux-ha/linux-ha/Makefile.am,v
retrieving revision 1.45
diff -u -r1.45 Makefile.am
--- Makefile.am 4 Jun 2004 02:32:32 -0000 1.45
+++ Makefile.am 22 Jun 2004 08:49:53 -0000
@@ -51,14 +51,20 @@
## proc-ha is left out from SUBDIRS (completely obsolete)
+if CRM_BUILD
+CRM_DIR = crm
+endif
+if LRM_BUILD
+LRM_DIR = lrm
+endif
+if SNMP_SUBAGENT_BUILD
+SNMP_SUBAGENT_DIR = snmp_subagent
+endif
+
SUBDIRS = libltdl doc debian pkg replace include lib \
ldirectord heartbeat telecom\
cts linux-ha membership contrib config \
- @SNMP_SUBAGENT_DIR@ @CRM_DIR@ @LRM_DIR@ tools
-
-DIST_SUBDIRS = libltdl doc debian pkg replace include lib \
- ldirectord heartbeat telecom cts linux-ha membership \
- contrib config @CRM_DIR@ @LRM_DIR@ tools
+ $(CRM_DIR) $(LRM_DIR) $(SNMP_SUBAGENT_DIR) tools
HANDY_DOCS = doc/ChangeLog doc/GettingStarted.html doc/DirectoryMap.txt
HBDOCS = doc/heartbeat_api.html
Index: configure.in
===================================================================
RCS file: /home/cvs/linux-ha/linux-ha/configure.in,v
retrieving revision 1.286
diff -u -r1.286 configure.in
--- configure.in 18 Jun 2004 18:27:58 -0000 1.286
+++ configure.in 22 Jun 2004 08:49:54 -0000
@@ -15,7 +15,7 @@
dnl Where #defines go (e.g. `AC_CHECK_HEADERS' below)
AM_CONFIG_HEADER(linux-ha/config.h include/ha_config.h)
ALL_LINGUAS="en fr"
-AM_INIT_AUTOMAKE(heartbeat, 1.3.0)
+AM_INIT_AUTOMAKE(heartbeat, 1.3.0.cvs.20040616)
RPMREL=1
AC_SUBST(RPMREL)
@@ -263,10 +263,13 @@
AC_MSG_RESULT(using ex2fs uuid)
elif test "$ac_cv_lib_uuid_uuid_create" = yes; then
AC_MSG_RESULT(using ossp uuid functionality)
-elif test "$enable_crm" = yes -o "$enable_lrm" = yes; then
- AC_MSG_ERROR("No UUID functuionality found. Needed for CRM/LRM");
else
- AC_MSG_WARN("No UUID functuionality found. Needed for CRM/LRM");
+ AC_MSG_RESULT(no UUID functuionality found)
+ if test "$enable_crm" = yes -o "$enable_lrm" = yes; then
+ AC_MSG_ERROR("UUID needed for CRM/LRM");
+ else
+ AC_MSG_WARN("UUID needed for CRM/LRM");
+ fi
fi
AC_SUBST(LIBNETDEFINES)
@@ -585,7 +588,7 @@
AC_CHECK_HEADERS(OpenIPMI/ipmi_auth.h)
-AC_MSG_CHECKING(for special libxml2 includes: )
+AC_MSG_CHECKING(for special libxml2 includes)
if test "x$XML2CONFIG" = "x"; then
AC_MSG_RESULT(libxml2 config not found)
else
@@ -975,21 +978,19 @@
NON_FATAL_CC_WARNINGS="$EXTRA_WARNINGS"
fi
-if test "${enable_snmp_subagent}" = "yes"; then
- echo "Enabling SNMP Sub Agent"
- SNMP_SUBAGENT_DIR="snmp_subagent"
+if test "x${enable_snmp_subagent}" = "xyes"; then
+ echo "Enabling SNMP Sub Agent"
sinclude([config/snmp_subagent.m4])
LIB_SNMP
SNMP_SUBAGENT_ENABLED=1
- AC_SUBST(SNMP_SUBAGENT_ENABLED)
- AC_SUBST(SNMP_LIBS)
else
+ enable_snmp_subagent="no"
SNMP_SUBAGENT_ENABLED=0
- AC_SUBST(SNMP_SUBAGENT_ENABLED)
- SNMP_SUBAGENT_DIR=""
fi
-AC_SUBST(SNMP_SUBAGENT_DIR)
+AM_CONDITIONAL(SNMP_SUBAGENT_BUILD, test "x${enable_snmp_subagent}" = "xyes")
+AC_SUBST(SNMP_SUBAGENT_ENABLED)
+AC_SUBST(SNMP_LIBS)
AC_MSG_CHECKING(which init (rc) directory to use)
INITDIR=""
@@ -1443,16 +1444,14 @@
AC_ARG_ENABLE([eventd],
[ --enable-eventd AIS Event Service daemon. [default=no] ])
-EVENTD_DIR=""
-if test "${enable_eventd}" = "yes"; then
+if test "x${enable_eventd}" = "xyes"; then
echo "Enabling the AIS Event Service code..."
- EVENTD_DIR="eventd"
else
if test -z "${enable_eventd}"; then
enable_eventd="no"
fi
fi
-AC_SUBST(EVENTD_DIR)
+AM_CONDITIONAL(EVENTD_BUILD, test "x${enable_eventd}" = "xyes")
#
# AIS Checkpoint Service
@@ -1460,27 +1459,22 @@
AC_ARG_ENABLE([checkpointd],
[ --enable-checkpointd AIS Checkpoint Service daemon. [default=no] ])
-CHECKPOINTD_DIR=""
-if test "${enable_checkpointd}" = "yes"; then
+if test "x${enable_checkpointd}" = "xyes"; then
echo "Enabling the AIS Checkpoint Service code..."
- CHECKPOINTD_DIR="checkpointd"
else
if test -z "${enable_checkpointd}"; then
enable_checkpointd="no"
fi
fi
-AC_SUBST(CHECKPOINTD_DIR)
+AM_CONDITIONAL(CHECKPOINTD_BUILD, test "x${enable_checkpointd}" = "xyes")
AC_ARG_ENABLE([crm],
[ --enable-crm Compile the new Cluster Resource Manager.
This is still in very early developement stage. [default=no]])
-CRM_DIR=""
-CRM_LIBS=""
CRM_ENABLED=0
-if test "${enable_crm}" = "yes"; then
+if test "x${enable_crm}" = "xyes"; then
if test -n "$XML2CONFIG"; then
- CRM_DIR="crm"
CRM_ENABLED=1
AC_DEFINE_UNQUOTED(WITH_CRM, 1, Use the new Cluster Resource Manager)
else
@@ -1495,9 +1489,8 @@
echo "$as_me:$LINENO: Enabling the new Cluster Resource Manager... ${enable_crm}" >&5
echo $ECHO_N "Enabling the new Cluster Resource Manager... ${enable_crm}" >&6
+AM_CONDITIONAL(CRM_BUILD, test "x${enable_crm}" = "xyes")
AC_SUBST(CRM_ENABLED)
-AC_SUBST(CRM_LIBS)
-AC_SUBST(CRM_DIR)
CRM_DEBUG_LIBS=""
CRM_DEBUG_OPTS=""
@@ -1514,29 +1507,23 @@
This is still in developement stage. [default=no]])
LRM_ENABLED=0
-LRM_DIR=""
-
-if test "${enable_crm}" = "yes"; then
- if test "${enable_lrm}" = "no"; then
+if test "x${enable_crm}" = "xyes"; then
+ if test "x${enable_lrm}" = "xno"; then
AC_MSG_WARN([crm enabled, overriding --enable-lrm=no with --enable-lrm=yes])
elif test -z "${enable_lrm}"; then
AC_MSG_WARN([crm enabled, defaulting to --enable-lrm=yes])
-dnl else
-dnl anything here?
fi
enable_lrm="yes"
-fi
-
-if test -z "${enable_lrm}"; then
+elif test -z "${enable_lrm}"; then
enable_lrm="no"
fi
-if test "${enable_lrm}" = "yes"; then
+if test "x${enable_lrm}" = "xyes"; then
LRM_ENABLED=1
- LRM_DIR="lrm"
fi
+
AC_SUBST(LRM_ENABLED)
-AC_SUBST(LRM_DIR)
+AM_CONDITIONAL(LRM_BUILD, test "x${enable_lrm}" = "xyes")
echo "$as_me:$LINENO: Enabling the new Local Resource Manager... ${enable_lrm}" >&5
echo $ECHO_N "Enabling the new Local Resource Manager... ${enable_lrm}" >&6
@@ -1547,7 +1534,6 @@
[ --enable-swig Provide language bindings via SWIG [default=no]])
SWIG_OPTIONS="$GLIBHEAD"
-SWIG_DIR=""
SWIG_ENABLED=0
if test -z "${enable_swig}"; then
enable_swig="no"
@@ -1564,21 +1550,12 @@
enable_swig="no (version 1.3.x, x>=19 required)"
AC_MSG_RESULT(swig version 1.3.x, x>=19 required)
else
- dnl - Get version
- dnl - May look like
- dnl This is perl, v5.8.2 built for i386-freebsd
- dnl This is perl, version 5.005_03 built for sun4-solaris
- dnl This is perl, v5.8.0 built for i386-linux-thread-multi
- PERL_VERSION="`$PERL -v 2>&1 | sed -ne 's/This is perl, v[ersion ]*//p' | sed -ne 's/ built for .*//p' | sed -ne 's/_.*//p'`"
- valid_ver="`$PERL -e \"if ('$PERL_VERSION' > '5.008001') { print 'yes';} else{ print 'no';}\"`"
- #if test "$PERL_VERSION" -lt "5.008001" 2>&1 ; then
- if test ${valid_ver} = "no"; then
- enable_swig="no"
- else
- dnl We seem to have passed all tests
+ if perl -e "use 5.008001;" >& /dev/null; then
SWIG_ENABLED=1
- SWIG_DIR="bindings"
- AC_DEFINE_UNQUOTED(WITH_SWIG, 1, SWIG bindings enabled)
+ AC_DEFINE_UNQUOTED(WITH_SWIG, 1,
+ SWIG bindings enabled)
+ else
+ enable_swig="no (invalid perl version)"
fi
fi
fi
@@ -1590,7 +1567,7 @@
AC_SUBST(SWIG_ENABLED)
AC_SUBST(SWIG_OPTIONS)
-AC_SUBST(SWIG_DIR)
+AM_CONDITIONAL(SWIG_BUILD, test "x${enable_swig}" = "xyes")
AC_ARG_ENABLE([perl-vendor],
[ --enable-perl-vendor Install the Perl bindings as vendor extensions [default=no]])
@@ -1612,19 +1589,10 @@
fi
-
-dnl testing if we can enable hbaping direcotory
-
-AC_CHECK_FILE(/usr/include/hbaapi.h,[ac_have_hbaapi_h="yes"],[],[])
-
-AC_CHECK_FILE(/usr/lib/libHBAAPI.so,[ac_have_hbaapi_lib="yes"],[],[])
-
-hbaping=""
-if test x"${ac_have_hbaapi_h}" = x"yes" && test x"${ac_have_hbaapi_lib}" = x"yes"; then
- hbaping="hbaping"
- AC_CONFIG_FILES(lib/plugins/HBcomm/hbaping/Makefile)
-fi
-AC_SUBST(hbaping)
+hbaping_build="yes"
+AC_CHECK_LIB(HBAAPI, HBA_SendScsiInquiry, , [hbaping_build="no"])
+AC_CHECK_HEADER(hbaapi.h, , [hbaping_build="no"])
+AM_CONDITIONAL(HBAAPI_BUILD, test "x${hbaping_build}" = "xyes")
dnl **********************************************************************
@@ -1647,6 +1615,13 @@
cts/CTSaudits.py \
cts/CTSlab.py \
cts/CTStests.py \
+crm/Makefile \
+ crm/common/Makefile \
+ crm/cib/Makefile \
+ crm/crmd/Makefile \
+ crm/pengine/Makefile \
+ crm/tengine/Makefile \
+ crm/admin/Makefile \
debian/Makefile \
doc/Makefile \
doc/startstop \
@@ -1654,7 +1629,11 @@
contrib/ipfail/Makefile \
contrib/mlock/Makefile \
include/Makefile \
+ include/checkpointd/Makefile \
include/clplumbing/Makefile \
+ include/crm/Makefile \
+ include/crm/common/Makefile \
+ include/lrm/Makefile \
include/ocf/Makefile \
include/pils/Makefile \
include/pils/plugin.h \
@@ -1664,21 +1643,34 @@
linux-ha/Makefile \
lib/Makefile \
lib/apphb/Makefile \
+ lib/bindings/Makefile \
+ lib/bindings/perl/Makefile \
+ lib/bindings/perl/Makefile.PL \
+ lib/bindings/perl/cl_raw/Makefile.PL \
+ lib/checkpointd/Makefile \
lib/clplumbing/Makefile \
+ lib/eventd/Makefile \
lib/hbclient/Makefile \
+ lib/lrm/Makefile \
lib/pils/Makefile \
lib/plugins/Makefile \
lib/plugins/InterfaceMgr/Makefile \
lib/plugins/HBauth/Makefile \
lib/plugins/HBcomm/Makefile \
+ lib/plugins/HBcomm/hbaping/Makefile \
+ lib/plugins/lrm/Makefile \
lib/plugins/stonith/Makefile \
lib/plugins/AppHBNotification/Makefile \
lib/recoverymgr/Makefile \
lib/stonith/Makefile \
+lrm/Makefile \
+ lrm/lrmd/Makefile \
+ lrm/admin/Makefile \
+ lrm/test/Makefile \
heartbeat/Makefile \
heartbeat/rc.d/Makefile \
heartbeat/rc.d/ask_resources \
- heartbeat/rc.d/hb_takeover
+ heartbeat/rc.d/hb_takeover \
heartbeat/init.d/Makefile \
heartbeat/init.d/heartbeat \
heartbeat/lib/Makefile \
@@ -1721,75 +1713,15 @@
membership/ccm/Makefile \
pkg/Makefile \
pkg/InfoFiles/pkginfo \
+snmp_subagent/Makefile \
telecom/Makefile \
telecom/apphbd/Makefile \
+ telecom/checkpointd/Makefile \
+ telecom/eventd/Makefile \
telecom/recoverymgrd/Makefile \
-tools/Makefile
-)
-
-dnl testing again makes the eventual output a little easier to read
-if test "${enable_crm}" = "yes"; then
- AC_CONFIG_FILES(crm/Makefile \
- include/crm/Makefile \
- include/crm/common/Makefile \
- crm/common/Makefile \
- crm/cib/Makefile \
- crm/crmd/Makefile \
- crm/pengine/Makefile \
- crm/tengine/Makefile \
- crm/admin/Makefile \
-)
-dnl else
-dnl For when the CRM is manditory...
-dnl if "${enable_crm}" = "no (libxml2 not found)"; then
-dnl exit(1);
-dnl fi
-fi
-
-dnl enable output Makefile for LRM compiling
-if test "${enable_lrm}" = "yes"; then
- AC_CONFIG_FILES(include/lrm/Makefile \
- lib/plugins/lrm/Makefile \
- lib/lrm/Makefile \
- lrm/Makefile \
- lrm/lrmd/Makefile \
- lrm/admin/Makefile \
- lrm/test/Makefile \
+tools/Makefile \
)
-fi
-
-if test "${enable_swig}" = "yes"; then
- AC_CONFIG_FILES(lib/bindings/Makefile \
- lib/bindings/perl/Makefile \
- lib/bindings/perl/Makefile.PL \
- lib/bindings/perl/cl_raw/Makefile.PL \
- )
-fi
-
-dnl if eventd is enabled
-if test "${enable_eventd}" = "yes"; then
- AC_CONFIG_FILES(telecom/eventd/Makefile \
- lib/eventd/Makefile \
- )
-fi
-
-dnl if checkpointd is enabled
-if test "${enable_checkpointd}" = "yes"; then
- AC_CONFIG_FILES(include/checkpointd/Makefile \
- lib/checkpointd/Makefile \
- telecom/checkpointd/Makefile \
- )
-fi
-
-
-dnl if snmp_subagent is enabled
-if test "${enable_snmp_subagent}" = "yes"; then
- AC_CONFIG_FILES(snmp_subagent/Makefile \
- )
-fi
-
-
dnl Now process the entire list of files added by previous
dnl calls to AC_CONFIG_FILES()
AC_OUTPUT()
@@ -1829,23 +1761,18 @@
AC_MSG_RESULT([ HA client user name = "${HA_CCMUSER}"])
AC_MSG_RESULT([ HA client user id = "${HA_CCMUID}"])
-case x"$SNMP_SUBAGENT_DIR" in
- x)
- AC_MSG_RESULT([ Build snmp subagent = no])
- ;;
- xsnmp_subagent)
- AC_MSG_RESULT([ Build snmp subagent = yes])
+AC_MSG_RESULT([ Build snmp subagent = "${enable_snmp_subagent}"])
+if test "x${enable_snmp_subagent}" = "xyes"; then
AC_MSG_RESULT([ ucd_snmp_devel name = "${UCDSNMPDEVEL}"])
AC_MSG_RESULT([ SNMP libraries = "${SNMP_LIBS}"])
AC_MSG_RESULT([ SNMP MIB directory = "${MIBS_DIR}"])
- ;;
-esac
+fi
-AC_MSG_RESULT([ Build New CRM = ${enable_crm}])
-AC_MSG_RESULT([ Build New LRM = ${enable_lrm}])
-AC_MSG_RESULT([ Build SWIG bindings = ${enable_swig}])
-AC_MSG_RESULT([ Build Eventd = ${enable_eventd}])
-AC_MSG_RESULT([ Build Checkpointd = ${enable_checkpointd}])
+AC_MSG_RESULT([ Build New CRM = "${enable_crm}"])
+AC_MSG_RESULT([ Build New LRM = "${enable_lrm}"])
+AC_MSG_RESULT([ Build SWIG bindings = "${enable_swig}"])
+AC_MSG_RESULT([ Build Eventd = "${enable_eventd}"])
+AC_MSG_RESULT([ Build Checkpointd = "${enable_checkpointd}"])
AC_MSG_RESULT([ CC_WARNINGS = "${CC_WARNINGS}"])
AC_MSG_RESULT([ Mangled CFLAGS = "${CFLAGS}"])
Index: debian/changelog
===================================================================
RCS file: /home/cvs/linux-ha/linux-ha/debian/changelog,v
retrieving revision 1.25
diff -u -r1.25 changelog
--- debian/changelog 20 May 2004 06:07:36 -0000 1.25
+++ debian/changelog 22 Jun 2004 08:49:54 -0000
@@ -1,3 +1,9 @@
+heartbeat (1.3.0.cvs.20040616-1) unstable; urgency=low
+
+ * Test
+
+ -- Simon Horman <horms at debian.org> Wed, 16 Jun 2004 15:17:28 +0900
+
heartbeat (1.2.2-5) unstable; urgency=low
* Fixed alignment error in IPv6addr.c that manifests on ia64
Index: include/Makefile.am
===================================================================
RCS file: /home/cvs/linux-ha/linux-ha/include/Makefile.am,v
retrieving revision 1.17
diff -u -r1.17 Makefile.am
--- include/Makefile.am 24 May 2004 06:12:26 -0000 1.17
+++ include/Makefile.am 22 Jun 2004 08:49:54 -0000
@@ -24,9 +24,20 @@
includedir=$(base_includedir)/heartbeat
+if CHECKPOINTD_BUILD
+CHECKPOINTD_DIR = checkpointd
+endif
+if CRM_BUILD
+CRM_DIR = crm
+endif
+if LRM_BUILD
+LRM_DIR = lrm
+endif
+
noinst_HEADERS = hb_api_core.h
include_HEADERS = apphb.h apphb_notify.h HBauth.h HBcomm.h \
ha_msg.h heartbeat.h hb_api.h ha_config.h \
recoverymgr.h
-SUBDIRS = clplumbing ocf pils saf @CHECKPOINTD_DIR@ stonith @LRM_DIR@ @CRM_DIR@
+SUBDIRS = clplumbing ocf pils saf $(CHECKPOINTD_DIR) \
+ stonith $(LRM_DIR) $(CRM_DIR)
Index: lib/Makefile.am
===================================================================
RCS file: /home/cvs/linux-ha/linux-ha/lib/Makefile.am,v
retrieving revision 1.16
diff -u -r1.16 Makefile.am
--- lib/Makefile.am 24 May 2004 06:12:26 -0000 1.16
+++ lib/Makefile.am 22 Jun 2004 08:49:55 -0000
@@ -19,6 +19,19 @@
#
MAINTAINERCLEANFILES = Makefile.in
+if EVENTD_BUILD
+EVENTD_DIR = eventd
+endif
+if CHECKPOINTD_BUILD
+CHECKPOINTD_DIR = checkpointd
+endif
+if SWIG_BUILD
+SWIG_DIR = bindings
+endif
+if LRM_BUILD
+LRM_DIR = lrm
+endif
+
#
# PILS is supposed to be an independent library
# Stonith should rely only on PILS
@@ -36,7 +49,7 @@
apphb \
recoverymgr \
plugins \
- @EVENTD_DIR@ \
- @CHECKPOINTD_DIR@ \
- @SWIG_DIR@ \
- @LRM_DIR@
+ $(CHECKPOINTD_DIR) \
+ $(EVENTD_DIR) \
+ $(SWIG_DIR) \
+ $(LRM_DIR)
Index: lib/bindings/perl/Makefile.am
===================================================================
RCS file: /home/cvs/linux-ha/linux-ha/lib/bindings/perl/Makefile.am,v
retrieving revision 1.5
diff -u -r1.5 Makefile.am
--- lib/bindings/perl/Makefile.am 9 Mar 2004 12:47:12 -0000 1.5
+++ lib/bindings/perl/Makefile.am 22 Jun 2004 08:49:55 -0000
@@ -20,6 +20,14 @@
noinst_DATA = .made_mod
+EXTRA_DIST = MANIFEST test.pl \
+ cl_raw/Makefile.PL.in cl_raw/Makefile.PL \
+ cl_raw/cl_log_wrappers.c cl_raw/cl_log_wrappers.h \
+ cl_raw/cl_raw.i \
+ cl_raw/ipc_wrappers.c cl_raw/ipc_wrappers.h \
+ lib/heartbeat/clplumbing/ipc.pm \
+ lib/heartbeat/clplumbing/log.pm
+
INCLUDES = -I$(top_builddir)/include -I$(top_srcdir)/include \
-I$(top_builddir)/linux-ha -I$(top_srcdir)/linux-ha \
-I$(top_builddir)/libltdl -I$(top_srcdir)/libltdl
@@ -29,18 +37,25 @@
-I$(top_builddir)/../libltdl -I$(top_srcdir)/../libltdl
Makefile.perl: Makefile.PL
- $(PERL) $<
+ ( old_pwd=`pwd` ; cd $(srcdir) && \
+ $(PERL) $< && \
+ test $@ -ef $$old_pwd/$@ || mv $@ $$old_pwd/; )
.made_mod: cl_raw/cl_raw.pm Makefile.perl
- $(MAKE) -fMakefile.perl INCLUDES="$(SUB_INCLUDES)"
+ ( old_pwd=`pwd` ; cd $(srcdir) && \
+ $(MAKE) -f$$old_pwd/Makefile.perl INCLUDES="$(SUB_INCLUDES)" )
touch $@
cl_raw/cl_raw.pm: cl_raw/cl_raw.i
- cd cl_raw && \
- $(SWIG) $(SWIG_OPTIONS) $(SUB_INCLUDES) -perl cl_raw.i
+ ( old_pwd=`pwd` ; cd $(srcdir)/cl_raw && \
+ $(SWIG) $(SWIG_OPTIONS) $(SUB_INCLUDES) -perl cl_raw.i && \
+ test cl_raw.pm -ef $$old_pwd/cl_raw/cl_raw.pm || \
+ mv $@ $$old_pwd/cl_raw/; )
install-data-local:
- $(MAKE) -fMakefile.perl PREFIX=$(prefix) $(PERL_INSTALL_TARGET)
+ ( old_pwd=`pwd` ; cd $(srcdir) && \
+ $(MAKE) -f$$old_pwd/Makefile.perl PREFIX=$(prefix) \
+ $(PERL_INSTALL_TARGET) )
CLEANFILES = .made_mod cl_raw/cl_raw.pm cl_raw/cl_raw_wrap.c
Index: lib/plugins/Makefile.am
===================================================================
RCS file: /home/cvs/linux-ha/linux-ha/lib/plugins/Makefile.am,v
retrieving revision 1.8
diff -u -r1.8 Makefile.am
--- lib/plugins/Makefile.am 26 Mar 2004 05:00:49 -0000 1.8
+++ lib/plugins/Makefile.am 22 Jun 2004 08:49:55 -0000
@@ -20,6 +20,9 @@
MAINTAINERCLEANFILES = Makefile.in
-## Subdirectories...
+if LRM_BUILD
+LRM_DIR = lrm
+endif
+
SUBDIRS = InterfaceMgr HBauth HBcomm stonith AppHBNotification \
- @LRM_DIR@
+ $(LRM_DIR)
Index: lib/plugins/HBcomm/Makefile.am
===================================================================
RCS file: /home/cvs/linux-ha/linux-ha/lib/plugins/HBcomm/Makefile.am,v
retrieving revision 1.15
diff -u -r1.15 Makefile.am
--- lib/plugins/HBcomm/Makefile.am 18 Jun 2004 18:24:03 -0000 1.15
+++ lib/plugins/HBcomm/Makefile.am 22 Jun 2004 08:49:55 -0000
@@ -19,7 +19,11 @@
#
MAINTAINERCLEANFILES = Makefile.in
-SUBDIRS = @hbaping@
+if HBAAPI_BUILD
+HBAAPI_DIR = hbaping
+endif
+
+SUBDIRS = $(HBAAPI_DIR)
INCLUDES = -I$(top_builddir)/include -I$(top_srcdir)/include \
-I$(top_builddir)/linux-ha -I$(top_srcdir)/linux-ha \
Index: telecom/Makefile.am
===================================================================
RCS file: /home/cvs/linux-ha/linux-ha/telecom/Makefile.am,v
retrieving revision 1.9
diff -u -r1.9 Makefile.am
--- telecom/Makefile.am 24 May 2004 06:12:26 -0000 1.9
+++ telecom/Makefile.am 22 Jun 2004 08:49:55 -0000
@@ -19,5 +19,11 @@
#
MAINTAINERCLEANFILES = Makefile.in
-## Subdirectories...
-SUBDIRS = apphbd recoverymgrd @EVENTD_DIR@ @CHECKPOINTD_DIR@
+if EVENTD_BUILD
+EVENTD_DIR = eventd
+endif
+if CHECKPOINTD_BUILD
+CHECKPOINTD_DIR = checkpointd
+endif
+
+SUBDIRS = apphbd recoverymgrd $(EVENTD_DIR) $(CHECKPOINTD_DIR)
More information about the Linux-HA-Dev
mailing list